Was wird benötigt

• Ein Server mit 15 oder mehr GB RAM und einem Windows Betriebssystem.
  • Das Hosting unter Linux wird aktuell offiziell nicht unterstützt!

Installation des Dedizierten Servers

Firewall-Einstellungen

Folgende eingehende Ports müssen in deiner Firewall und oder deinem Router freigeschaltet sein:

• 27015 (ServerPort)
• 27016 (ServerQueryPort)
• 27017 (RconPort)

Installation

• Installiere Visual C++ Redistributable https://aka.ms/vs/17/release/vc_redist.x64.exe
• Lege auf Laufwerk C einen Ordner SteamCMD an.
• Lege auf Laufwerk C einen neuen Ordner ASAServer an und in diesem einen Ordner mit dem Namen Server1.
• Lege eine start.bat irgendwo dort an, wo du sie wiederfindest und kopiere dort folgenden Inhalt rein:

@echo off
:: Setup
set STEAMCMDDIR="C:\SteamCMD\"
set SERVERDIR="C:\ASAServer\Server1\"
set ARKAPPID=2430930

::ASA Server Settings
set SERVERMAP=TheIsland_WP
set SERVERPORT=27015
set SERVERQUERYPORT=27016
set RCONPORT=27017
set SERVERADMINPASSWORD=Adminpasswort
set SERVERMAXPLAYERS=20
set CLUSTERID=
set CLUSTERDIR=""
set SERVERMODS=
set PASSIVEMODS=

if not "%SERVERMODS%"=="" (
    set MODS_PARAM=-mods=%SERVERMODS%
) else (
    set MODS_PARAM=
)

if not "%PASSIVEMODS%"=="" (
    set PMODS_PARAM=-passivemods=%PASSIVEMODS%
) else (
    set PMODS_PARAM=
)

if not "%RCONPORT%"=="" (
    set RCON_PARAM=?RCONPort=%RCONPORT%?RCONEnabled=True
) else (
    set RCON_PARAM=
)

if not "%CLUSTERID%"=="" (
    set CLUSTER_PARAM=-NoTransferFromFiltering -clusterid=%CLUSTERID%
) else (
    set CLUSTER_PARAM=
)

if not "%CLUSTERDIR%"=="" (
    set CLUSTERDIR_PARAM=-ClusterDirOverride=%CLUSTERDIR%
) else (
    set CLUSTERDIR_PARAM=
)

::Start/Updatescript
:run
cls
echo (%time% ) - Server wird via Steam geupdated...


cd /d %STEAMCMDDIR%
del steamcmd.exe
timeout /t 5 /nobreak
curl -o steamcmd.zip https://steamcdn-a.akamaihd.net/client/installer/steamcmd.zip
powershell Expand-Archive -Path .\steamcmd.zip -DestinationPath .\
start "" /wait steamcmd.exe +force_install_dir "%SERVERDIR%" +login anonymous +app_update %ARKAPPID% validate +quit

echo (%time% ) - ASA DS wird gestartet...

cd /d %SERVERDIR%
ShooterGame\Binaries\Win64\ArkAscendedServer.exe %SERVERMAP%?listen?Port=%SERVERPORT%?QueryPort=%SERVERQUERYPORT%%RCON_PARAM%?ServerAdminPassword=%SERVERADMINPASSWORD% -WinLiveMaxPlayers=%SERVERMAXPLAYERS% %MODS_PARAM% %PMODS_PARAM% %CLUSTER_PARAM% %CLUSTERDIR_PARAM% -culture=en -log

cls
echo (%time% ) - Serverprozess unterbrochen! Neustartsquenz läuft...

timeout /t 15
goto run

• SERVERMAP= Hier wird der Map Name angegeben, mit welcher der Server starten soll.

  • Aktuelle Offizielle Maps: TheIsland_WP ScorchedEarth_WP TheCenter_WP Aberration_WP

• SERVERPORT= Hier wird der Port des Servers angegeben. Dieser muss ggf. in der Firewall freigeschalten werden.

  • Sollte dein Server bei dir Zuhause laufen, dann musst du diesen Port ggf. noch in deinem Router entsprechend freischalten/weiterleiten.

• SERVERQUERYPORT= Hier wird der QueryPort des Servers angegeben. Dieser muss ggf. in der Firewall freigeschalten werden.

  • Sollte dein Server bei dir Zuhause laufen, dann musst du diesen Port ggf. noch in deinem Router entsprechend freischalten/weiterleiten.

• RCONPORT= Lege hier einen Port für den Rcon fest, Sollte ein Port festgelegt sein, wird Rcon automatisch aktiviert.

• SERVERADMINPASSWORD= Hiermit legst das Admin-Passwort für deinen Server fest. Du kannst im Spiel über die Cheat Konsole mit dem Befehl enablecheats PASSWORT die Adminrechte freischalten.

• SERVERMAXPLAYERS= legt die Maximale Anzahl der Spieler fest, die auf deinem Server gleichzeitig spielen dürfen.

• CLUSTERID= Lege hier eine Id für deinen Cluster fest, dieses ID sollte auf allen Servern im Cluster gleich sein.

• CLUSTERDIR= Lege hier ein Speicherort für die ARK-Daten des Clusters fest. Das Verzeichnis sollte für alle Server im Cluster das selbe sein.

• SERVERMODS= (siehe Abschnitt Mods).

Passe ggf. die Port=7777 und QueryPort=27015 deinen wünschen an, achte darauf, entsprechende Ports in deiner Firewall und oder deinem Router freizuschalten.

Du kannst die Pfade STEAMCMDDIR (Zeile 3) und SERVERDIR (Zeile 4) entsprechend deinen Wünschen anpassen.

Du kannst mehrere Server auf deinem Root-Server ausführen!

Konfiguration

Im Verzeichnis C:\ASAServer\ShooterGame\Saved\Config\WindowsServer findest du die GameUserSettings.ini und die Game.ini. Über diese Dateien kannst du deinen Server Konfigurieren. Dazu werden wir später noch weitere Informationen schreiben. Sollten diese Dateien nicht da sein, diese einfach anlegen.

Die Speicherstände findest du unter:

C:\ASAServer\ShooterGame\Saved\SavedArks

Sicherheit

Sofern ihr einen Server ohne Cluster verwendet, sollten diese Einstellungen in der GameUserSettings.ini gesetzt werden.

PreventDownloadSurvivors=true
PreventDownloadItems=true
PreventDownloadDinos=true
PreventUploadSurvivors=true
PreventUploadItems=true
PreventUploadDinos=true
noTributeDownloads=true
NoTransferFromFiltering=True

Damit wird verhindert, dass Items, Dinos und Chars vom Singelplayer oder anderen Servern auf euren übertragen werden können oder von eurem Server in den Singelplayer oder auf andere Server Transferiert werden können.

Mods

Um auf eurem ARK: Survival Ascended Server Mods zu Installieren zu können, geht ihr wie folgt vor:

• Geht auf: https://curseforge.com/ark-survival-ascended und sucht euch die Mods heraus, die auf dem Server installiert werden sollen.
• Kopiert euch die Project ID der entsprechenden Mods. 
• Fügt dem Startscript hinter SERVERMODS= die entsprechenden ModIDs hinzu. Mehrere IDs werden mit einem , getrennt.
  • SERVERMODS=912902,900062 In diesem Beispiel Installieren wir Additions Ascended: Deinosuchus mit der Project ID: 912902 und Additions Ascended: Ceratosaurus mit der Project ID: 900062
• Die Mods werden bei jedem Neustart des Servers aktualisiert.

Starten des Servers

Um den Server zu starten und zu updaten, führst du einfach die angelegte start.bat aus.

Du kannst deinen Server nun in der Serverliste im Spiel finden.

Sollte sich das Fenster nach dem ausführen der start.bat gleich wieder schließen, führe es bitte als Administrator aus.

Beheben von Problemen

• Dein Server wird in der Serverliste nicht gefunden?
  • Stelle sicher, dass alle benötigen Ports in der Firewall freigeschalten wurden.
  • Installiere folgendes Zertifikat: crt.r2m02.amazontrust.com/r2m02.cer (in die Adresszeile des Browsers einfügen).
• Beim Installieren von Mods tritt folgender Fehler auf:  LogCFCore: Error: Error querying server mods: ApiError: Failed (serverUnreachable)
  • Installiere folgendes Zertifikat: crt.r2m02.amazontrust.com/r2m02.cer (in die Adresszeile des Browsers einfügen).

Probleme und Fragen

Solltest du Fragen oder Probleme mit der Einrichtung deines ARK: Survival Ascended Servers (ASA) haben, kannst du jederzeit bei uns im Forum ein Thema erstellen.

Klicke hier...